package be.simplenotes

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    java
    kotlin("jvm")
    `java-library`
}

repositories {
    mavenLocal()
    mavenCentral()
    jcenter()
    maven { url = uri("https://dl.bintray.com/arrow-kt/arrow-kt/") }
    maven { url = uri("https://kotlin.bintray.com/kotlinx") }
}

group = "be.simplenotes"
version = "1.0-SNAPSHOT"

dependencies {
    implementation(kotlin("stdlib-jdk8"))
}

tasks.withType<Test> {
    useJUnitPlatform()
}

java {
    sourceCompatibility = JavaVersion.VERSION_14
    targetCompatibility = JavaVersion.VERSION_14
}

sourceSets {
    val test by getting
    test.resources.srcDir("${rootProject.projectDir}/simplenotes-test-resources/src/test/resources")
}

tasks.withType<KotlinCompile> {
    kotlinOptions {
        jvmTarget = "14"
        javaParameters = true
        freeCompilerArgs = listOf(
            "-Xinline-classes",
            "-Xno-param-assertions",
            "-Xno-call-assertions",
            "-Xno-receiver-assertions"
        )
    }
}

tasks.withType<JavaCompile> {
    options.encoding = "UTF-8"
}