Initial commit

buildSrc/build.gradle.kts

@@ -0,0 +1,16 @@
+plugins {
+    `kotlin-dsl`
+}
+
+kotlinDslPluginOptions {
+    experimentalWarning.set(false)
+}
+
+repositories {
+    gradlePluginPortal()
+}
+
+dependencies {
+    implementation(platform("org.jetbrains.kotlin:kotlin-bom:1.4.31"))
+    implementation("org.jetbrains.kotlin:kotlin-gradle-plugin:1.4.31")
+}

buildSrc/src/main/kotlin/java-convention.gradle.kts

@@ -0,0 +1,26 @@
+plugins {
+    java
+}
+
+repositories {
+    mavenCentral()
+    maven {
+        url = uri("https://kotlin.bintray.com/kotlinx")
+        // https://github.com/Kotlin/kotlinx.html/issues/173
+        content { includeModule("org.jetbrains.kotlinx", "kotlinx-html-jvm") }
+    }
+}
+
+java {
+    targetCompatibility = JavaVersion.toVersion(15)
+    sourceCompatibility = JavaVersion.toVersion(15)
+}
+
+tasks.withType<JavaCompile> {
+    options.encoding = "UTF-8"
+}
+
+sourceSets["main"].resources.setSrcDirs(listOf("resources"))
+sourceSets["main"].java.setSrcDirs(emptyList<String>())
+sourceSets["test"].resources.setSrcDirs(listOf("test-resources"))
+sourceSets["test"].java.setSrcDirs(emptyList<String>())

buildSrc/src/main/kotlin/kotlin-application.gradle.kts

@@ -0,0 +1,4 @@
+plugins {
+    id("kotlin-convention")
+    application
+}

buildSrc/src/main/kotlin/kotlin-convention.gradle.kts

@@ -0,0 +1,32 @@
+import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
+
+plugins {
+    id("java-convention")
+    kotlin("jvm")
+}
+
+dependencies {
+    implementation(kotlin("stdlib-jdk8"))
+    implementation(platform(kotlin("bom")))
+    testImplementation("io.kotest:kotest-runner-junit5:4.4.1")
+}
+
+tasks.withType<Test> {
+    useJUnitPlatform()
+}
+
+tasks.withType<KotlinCompile> {
+    kotlinOptions {
+        jvmTarget = "15"
+        javaParameters = true
+        freeCompilerArgs = listOf("-Xopt-in=kotlin.RequiresOptIn")
+    }
+}
+
+kotlin {
+    sourceSets.all {
+        languageSettings.enableLanguageFeature("InlineClasses")
+    }
+    sourceSets["main"].kotlin.setSrcDirs(listOf("src"))
+    sourceSets["test"].kotlin.setSrcDirs(listOf("test"))
+}

buildSrc/src/main/kotlin/kotlin-library.gradle.kts

@@ -0,0 +1,4 @@
+plugins {
+    id("kotlin-convention")
+    `java-library`
+}